CMakeLua/Modules/FindCVS.cmake

   1 # The module defines the following variables:
   2 #   CVS_EXECUTABLE - path to cvs command line client
   3 #   CVS_FOUND - true if the command line client was found
   4 # Example usage:
   5 #   find_package(CVS)
   6 #   if(CVS_FOUND)
   7 #     message("CVS found: ${CVS_EXECUTABLE}")
   8 #   endif(CVS_FOUND)
   9
  10 # CVSNT
  11
  12 get_filename_component(
  13   CVSNT_TypeLib_Win32
  14   "[HKEY_CLASSES_ROOT\\TypeLib\\{2BDF7A65-0BFE-4B1A-9205-9AB900C7D0DA}\\1.0\\0\\win32]"
  15   PATH)
  16
  17 get_filename_component(
  18   CVSNT_Services_EventMessagePath
  19   "[HKEY_LOCAL_MACHINE\\SYSTEM\\ControlSet001\\Services\\Eventlog\\Application\\cvsnt;EventMessageFile]"
  20   PATH)
  21
  22 # WinCVS (in case CVSNT was installed in the same directory)
  23
  24 get_filename_component(
  25   WinCVS_Folder_Command
  26   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Classes\\Folder\\shell\\wincvs\\command]"
  27   PATH)
  28
  29 # TortoiseCVS (in case CVSNT was installed in the same directory)
  30
  31 get_filename_component(
  32   TortoiseCVS_Folder_Command
  33   "[HKEY_CLASSES_ROOT\\CVS\\shell\\open\\command]"
  34   PATH)
  35
  36 get_filename_component(
  37   TortoiseCVS_DefaultIcon
  38   "[HKEY_CLASSES_ROOT\\CVS\\DefaultIcon]"
  39   PATH)
  40
  41 find_program(CVS_EXECUTABLE cvs
  42   ${TortoiseCVS_DefaultIcon}
  43   ${TortoiseCVS_Folder_Command}
  44   ${WinCVS_Folder_Command}
  45   ${CVSNT_Services_EventMessagePath}
  46   ${CVSNT_TypeLib_Win32}
  47   "[HKEY_LOCAL_MACHINE\\SOFTWARE\\CVS\\Pserver;InstallPath]"
  48   DOC "CVS command line client"
  49   )
  50 mark_as_advanced(CVS_EXECUTABLE)
  51
  52 # Handle the QUIETLY and REQUIRED arguments and set CVS_FOUND to TRUE if
  53 # all listed variables are TRUE
  54
  55 include(FindPackageHandleStandardArgs)
  56 find_package_handle_standard_args(CVS DEFAULT_MSG CVS_EXECUTABLE)