gpxsee.pro

   1 unix:!macx:!android {
   2     TARGET = gpxsee
   3 } else {
   4     TARGET = GPXSee
   5 }
   6 VERSION = 13.20
   7
   8
   9 QT += core \
  10     gui \
  11     gui-private \
  12     network \
  13     sql \
  14     concurrent \
  15     widgets \
  16     printsupport \
  17     positioning \
  18     svg \
  19     serialport
  20 greaterThan(QT_MAJOR_VERSION, 5) {
  21     QT += openglwidgets
  22 }
  23
  24 CONFIG += object_parallel_to_source
  25 INCLUDEPATH += ./src
  26 HEADERS += src/common/config.h \
  27     src/common/garmin.h \
  28     src/common/coordinates.h \
  29     src/common/hash.h \
  30     src/common/linec.h \
  31     src/common/range.h \
  32     src/common/rectc.h \
  33     src/common/textcodec.h \
  34     src/common/treenode.h \
  35     src/common/wgs84.h \
  36     src/common/util.h \
  37     src/common/rtree.h \
  38     src/common/kv.h \
  39     src/common/greatcircle.h \
  40     src/common/programpaths.h \
  41     src/common/tifffile.h \
  42     src/common/downloader.h \
  43     src/common/polygon.h \
  44     src/common/color.h \
  45     src/common/csv.h \
  46     src/common/dem.h \
  47     src/common/demloader.h \
  48     src/GUI/crosshairitem.h \
  49     src/GUI/motioninfoitem.h \
  50     src/GUI/pluginparameters.h \
  51     src/GUI/authenticationwidget.h \
  52     src/GUI/axislabelitem.h \
  53     src/GUI/dirselectwidget.h \
  54     src/GUI/flowlayout.h \
  55     src/GUI/graphicsscene.h \
  56     src/GUI/infolabel.h \
  57     src/GUI/mapaction.h \
  58     src/GUI/mapitem.h \
  59     src/GUI/marginswidget.h \
  60     src/GUI/markerinfoitem.h \
  61     src/GUI/planeitem.h \
  62     src/GUI/poiaction.h \
  63     src/GUI/popup.h \
  64     src/GUI/thumbnail.h \
  65     src/GUI/app.h \
  66     src/GUI/icons.h \
  67     src/GUI/gui.h \
  68     src/GUI/axisitem.h \
  69     src/GUI/keys.h \
  70     src/GUI/slideritem.h \
  71     src/GUI/markeritem.h \
  72     src/GUI/infoitem.h \
  73     src/GUI/elevationgraph.h \
  74     src/GUI/speedgraph.h \
  75     src/GUI/sliderinfoitem.h \
  76     src/GUI/filebrowser.h \
  77     src/GUI/units.h \
  78     src/GUI/scaleitem.h \
  79     src/GUI/graphview.h \
  80     src/GUI/waypointitem.h \
  81     src/GUI/palette.h \
  82     src/GUI/heartrategraph.h \
  83     src/GUI/trackinfo.h \
  84     src/GUI/fileselectwidget.h \
  85     src/GUI/temperaturegraph.h \
  86     src/GUI/graphtab.h \
  87     src/GUI/trackitem.h \
  88     src/GUI/tooltip.h \
  89     src/GUI/routeitem.h \
  90     src/GUI/graphitem.h \
  91     src/GUI/pathitem.h \
  92     src/GUI/griditem.h \
  93     src/GUI/format.h \
  94     src/GUI/cadencegraph.h \
  95     src/GUI/powergraph.h \
  96     src/GUI/gearratiograph.h \
  97     src/GUI/optionsdialog.h \
  98     src/GUI/colorbox.h \
  99     src/GUI/stylecombobox.h \
 100     src/GUI/timetype.h \
 101     src/GUI/percentslider.h \
 102     src/GUI/elevationgraphitem.h \
 103     src/GUI/speedgraphitem.h \
 104     src/GUI/heartrategraphitem.h \
 105     src/GUI/temperaturegraphitem.h \
 106     src/GUI/cadencegraphitem.h \
 107     src/GUI/powergraphitem.h \
 108     src/GUI/gearratiographitem.h \
 109     src/GUI/oddspinbox.h \
 110     src/GUI/settings.h \
 111     src/GUI/searchpointer.h \
 112     src/GUI/mapview.h \
 113     src/GUI/font.h \
 114     src/GUI/areaitem.h \
 115     src/GUI/coordinatesitem.h \
 116     src/GUI/projectioncombobox.h \
 117     src/GUI/pathtickitem.h \
 118     src/GUI/pdfexportdialog.h \
 119     src/GUI/pngexportdialog.h \
 120     src/GUI/timezoneinfo.h \
 121     src/GUI/passwordedit.h \
 122     src/data/gpsdumpparser.h \
 123     src/data/style.h \
 124     src/data/twonavparser.h \
 125     src/map/ENC/attributes.h \
 126     src/map/ENC/mapdata.h \
 127     src/map/ENC/atlasdata.h \
 128     src/map/ENC/objects.h \
 129     src/map/ENC/rastertile.h \
 130     src/map/ENC/style.h \
 131     src/map/IMG/dem.h \
 132     src/map/IMG/demfile.h \
 133     src/map/IMG/demtile.h \
 134     src/map/IMG/jls.h \
 135     src/map/IMG/section.h \
 136     src/map/IMG/zoom.h \
 137     src/map/conversion.h \
 138     src/map/encatlas.h \
 139     src/map/encjob.h \
 140     src/map/encmap.h \
 141     src/map/ENC/iso8211.h \
 142     src/map/filter.h \
 143     src/map/gemfmap.h \
 144     src/map/gmifile.h \
 145     src/map/oruxmap.h \
 146     src/map/osmdroidmap.h \
 147     src/map/proj/polyconic.h \
 148     src/map/proj/webmercator.h \
 149     src/map/proj/transversemercator.h \
 150     src/map/proj/latlon.h \
 151     src/map/proj/lambertconic.h \
 152     src/map/proj/lambertazimuthal.h \
 153     src/map/proj/albersequal.h \
 154     src/map/proj/mercator.h \
 155     src/map/proj/krovak.h \
 156     src/map/proj/polarstereographic.h \
 157     src/map/proj/obliquestereographic.h \
 158     src/map/bitmapline.h \
 159     src/map/IMG/bitstream.h \
 160     src/map/IMG/deltastream.h \
 161     src/map/IMG/gmapdata.h \
 162     src/map/IMG/huffmanbuffer.h \
 163     src/map/IMG/huffmanstream.h \
 164     src/map/IMG/huffmantable.h \
 165     src/map/IMG/huffmantext.h \
 166     src/map/IMG/nodfile.h \
 167     src/map/IMG/mapdata.h \
 168     src/map/IMG/raster.h \
 169     src/map/IMG/rastertile.h \
 170     src/map/IMG/shield.h \
 171     src/map/IMG/imgdata.h \
 172     src/map/IMG/subfile.h \
 173     src/map/IMG/trefile.h \
 174     src/map/IMG/rgnfile.h \
 175     src/map/IMG/lblfile.h \
 176     src/map/IMG/vectortile.h \
 177     src/map/IMG/subdiv.h \
 178     src/map/IMG/style.h \
 179     src/map/IMG/netfile.h \
 180     src/map/IMG/label.h \
 181     src/map/mapsforge/style.h \
 182     src/map/mapsforge/mapdata.h \
 183     src/map/mapsforge/rastertile.h \
 184     src/map/mapsforge/subfile.h \
 185     src/map/qctmap.h \
 186     src/map/textpathitem.h \
 187     src/map/textpointitem.h \
 188     src/map/prjfile.h \
 189     src/map/bsbmap.h \
 190     src/map/invalidmap.h \
 191     src/map/kmzmap.h \
 192     src/map/projection.h \
 193     src/map/ellipsoid.h \
 194     src/map/datum.h \
 195     src/map/sqlitemap.h \
 196     src/map/utm.h \
 197     src/map/map.h \
 198     src/map/maplist.h \
 199     src/map/onlinemap.h \
 200     src/map/tile.h \
 201     src/map/emptymap.h \
 202     src/map/ozimap.h \
 203     src/map/tar.h \
 204     src/map/ozf.h \
 205     src/map/atlas.h \
 206     src/map/matrix.h \
 207     src/map/geotiff.h \
 208     src/map/pcs.h \
 209     src/map/transform.h \
 210     src/map/mapfile.h \
 211     src/map/gcs.h \
 212     src/map/angularunits.h \
 213     src/map/primemeridian.h \
 214     src/map/linearunits.h \
 215     src/map/ct.h \
 216     src/map/mapsource.h \
 217     src/map/tileloader.h \
 218     src/map/wldfile.h \
 219     src/map/wmtsmap.h \
 220     src/map/wmts.h \
 221     src/map/wmsmap.h \
 222     src/map/wms.h \
 223     src/map/crs.h \
 224     src/map/coordinatesystem.h \
 225     src/map/pointd.h \
 226     src/map/rectd.h \
 227     src/map/geocentric.h \
 228     src/map/jnxmap.h \
 229     src/map/geotiffmap.h \
 230     src/map/image.h \
 231     src/map/mbtilesmap.h \
 232     src/map/osm.h \
 233     src/map/rmap.h \
 234     src/map/calibrationpoint.h \
 235     src/map/textitem.h \
 236     src/map/aqmmap.h \
 237     src/map/mapsforgemap.h \
 238     src/map/worldfilemap.h \
 239     src/map/imgmap.h \
 240     src/map/hillshading.h \
 241     src/data/itnparser.h \
 242     src/data/link.h \
 243     src/data/onmoveparsers.h \
 244     src/data/ov2parser.h \
 245     src/data/graph.h \
 246     src/data/poi.h \
 247     src/data/waypoint.h \
 248     src/data/track.h \
 249     src/data/route.h \
 250     src/data/trackpoint.h \
 251     src/data/data.h \
 252     src/data/parser.h \
 253     src/data/trackdata.h \
 254     src/data/routedata.h \
 255     src/data/path.h \
 256     src/data/gpxparser.h \
 257     src/data/tcxparser.h \
 258     src/data/csvparser.h \
 259     src/data/kmlparser.h \
 260     src/data/fitparser.h \
 261     src/data/igcparser.h \
 262     src/data/nmeaparser.h \
 263     src/data/oziparsers.h \
 264     src/data/locparser.h \
 265     src/data/slfparser.h \
 266     src/data/area.h \
 267     src/data/exifparser.h \
 268     src/data/cupparser.h \
 269     src/data/gpiparser.h \
 270     src/data/address.h \
 271     src/data/smlparser.h \
 272     src/data/geojsonparser.h
 273
 274 SOURCES += src/main.cpp \
 275     src/common/coordinates.cpp \
 276     src/common/rectc.cpp \
 277     src/common/range.cpp \
 278     src/common/textcodec.cpp \
 279     src/common/util.cpp \
 280     src/common/greatcircle.cpp \
 281     src/common/programpaths.cpp \
 282     src/common/tifffile.cpp \
 283     src/common/downloader.cpp \
 284     src/common/csv.cpp \
 285     src/common/dem.cpp \
 286     src/common/demloader.cpp \
 287     src/GUI/crosshairitem.cpp \
 288     src/GUI/motioninfoitem.cpp \
 289     src/GUI/pluginparameters.cpp \
 290     src/GUI/settings.cpp \
 291     src/GUI/authenticationwidget.cpp \
 292     src/GUI/axislabelitem.cpp \
 293     src/GUI/dirselectwidget.cpp \
 294     src/GUI/flowlayout.cpp \
 295     src/GUI/infolabel.cpp \
 296     src/GUI/mapitem.cpp \
 297     src/GUI/marginswidget.cpp \
 298     src/GUI/markerinfoitem.cpp \
 299     src/GUI/popup.cpp \
 300     src/GUI/thumbnail.cpp \
 301     src/GUI/app.cpp \
 302     src/GUI/gui.cpp \
 303     src/GUI/axisitem.cpp \
 304     src/GUI/slideritem.cpp \
 305     src/GUI/markeritem.cpp \
 306     src/GUI/infoitem.cpp \
 307     src/GUI/elevationgraph.cpp \
 308     src/GUI/speedgraph.cpp \
 309     src/GUI/sliderinfoitem.cpp \
 310     src/GUI/filebrowser.cpp \
 311     src/GUI/scaleitem.cpp \
 312     src/GUI/graphview.cpp \
 313     src/GUI/waypointitem.cpp \
 314     src/GUI/palette.cpp \
 315     src/GUI/heartrategraph.cpp \
 316     src/GUI/trackinfo.cpp \
 317     src/GUI/fileselectwidget.cpp \
 318     src/GUI/temperaturegraph.cpp \
 319     src/GUI/trackitem.cpp \
 320     src/GUI/routeitem.cpp \
 321     src/GUI/graphitem.cpp \
 322     src/GUI/pathitem.cpp \
 323     src/GUI/griditem.cpp \
 324     src/GUI/format.cpp \
 325     src/GUI/cadencegraph.cpp \
 326     src/GUI/powergraph.cpp \
 327     src/GUI/gearratiograph.cpp \
 328     src/GUI/optionsdialog.cpp \
 329     src/GUI/colorbox.cpp \
 330     src/GUI/stylecombobox.cpp \
 331     src/GUI/oddspinbox.cpp \
 332     src/GUI/percentslider.cpp \
 333     src/GUI/elevationgraphitem.cpp \
 334     src/GUI/speedgraphitem.cpp \
 335     src/GUI/heartrategraphitem.cpp \
 336     src/GUI/temperaturegraphitem.cpp \
 337     src/GUI/cadencegraphitem.cpp \
 338     src/GUI/powergraphitem.cpp \
 339     src/GUI/gearratiographitem.cpp \
 340     src/GUI/mapview.cpp \
 341     src/GUI/areaitem.cpp \
 342     src/GUI/coordinatesitem.cpp \
 343     src/GUI/pathtickitem.cpp \
 344     src/GUI/graphicsscene.cpp \
 345     src/GUI/pdfexportdialog.cpp \
 346     src/GUI/pngexportdialog.cpp \
 347     src/GUI/projectioncombobox.cpp \
 348     src/GUI/passwordedit.cpp \
 349     src/map/ENC/atlasdata.cpp \
 350     src/map/ENC/mapdata.cpp \
 351     src/map/ENC/rastertile.cpp \
 352     src/map/ENC/style.cpp \
 353     src/map/IMG/dem.cpp \
 354     src/map/IMG/demfile.cpp \
 355     src/map/IMG/jls.cpp \
 356     src/map/conversion.cpp \
 357     src/map/encatlas.cpp \
 358     src/map/encmap.cpp \
 359     src/map/ENC/iso8211.cpp \
 360     src/map/filter.cpp \
 361     src/map/gemfmap.cpp \
 362     src/map/gmifile.cpp \
 363     src/map/oruxmap.cpp \
 364     src/map/osmdroidmap.cpp \
 365     src/map/proj/polyconic.cpp \
 366     src/map/proj/webmercator.cpp \
 367     src/map/proj/transversemercator.cpp \
 368     src/map/proj/lambertconic.cpp \
 369     src/map/proj/albersequal.cpp \
 370     src/map/proj/lambertazimuthal.cpp \
 371     src/map/proj/mercator.cpp \
 372     src/map/proj/krovak.cpp \
 373     src/map/proj/polarstereographic.cpp \
 374     src/map/proj/obliquestereographic.cpp \
 375     src/map/bitmapline.cpp \
 376     src/map/IMG/bitstream.cpp \
 377     src/map/IMG/deltastream.cpp \
 378     src/map/IMG/gmapdata.cpp \
 379     src/map/IMG/huffmanbuffer.cpp \
 380     src/map/IMG/huffmanstream.cpp \
 381     src/map/IMG/huffmantable.cpp \
 382     src/map/IMG/huffmantext.cpp \
 383     src/map/IMG/nodfile.cpp \
 384     src/map/IMG/mapdata.cpp \
 385     src/map/IMG/rastertile.cpp \
 386     src/map/IMG/imgdata.cpp \
 387     src/map/IMG/subfile.cpp \
 388     src/map/IMG/trefile.cpp \
 389     src/map/IMG/rgnfile.cpp \
 390     src/map/IMG/lblfile.cpp \
 391     src/map/IMG/vectortile.cpp \
 392     src/map/IMG/style.cpp \
 393     src/map/IMG/netfile.cpp \
 394     src/map/mapsforge/style.cpp \
 395     src/map/mapsforge/mapdata.cpp \
 396     src/map/mapsforge/rastertile.cpp \
 397     src/map/mapsforge/subfile.cpp \
 398     src/map/imgmap.cpp \
 399     src/map/prjfile.cpp \
 400     src/map/qctmap.cpp \
 401     src/map/textpathitem.cpp \
 402     src/map/textpointitem.cpp \
 403     src/map/bsbmap.cpp \
 404     src/map/kmzmap.cpp \
 405     src/map/maplist.cpp \
 406     src/map/onlinemap.cpp \
 407     src/map/emptymap.cpp \
 408     src/map/ozimap.cpp \
 409     src/map/sqlitemap.cpp \
 410     src/map/tar.cpp \
 411     src/map/atlas.cpp \
 412     src/map/ozf.cpp \
 413     src/map/matrix.cpp \
 414     src/map/ellipsoid.cpp \
 415     src/map/datum.cpp \
 416     src/map/utm.cpp \
 417     src/map/geotiff.cpp \
 418     src/map/pcs.cpp \
 419     src/map/transform.cpp \
 420     src/map/mapfile.cpp \
 421     src/map/projection.cpp \
 422     src/map/gcs.cpp \
 423     src/map/angularunits.cpp \
 424     src/map/primemeridian.cpp \
 425     src/map/linearunits.cpp \
 426     src/map/mapsource.cpp \
 427     src/map/tileloader.cpp \
 428     src/map/wldfile.cpp \
 429     src/map/wmtsmap.cpp \
 430     src/map/wmts.cpp \
 431     src/map/wmsmap.cpp \
 432     src/map/wms.cpp \
 433     src/map/crs.cpp \
 434     src/map/coordinatesystem.cpp \
 435     src/map/geocentric.cpp \
 436     src/map/jnxmap.cpp \
 437     src/map/map.cpp \
 438     src/map/geotiffmap.cpp \
 439     src/map/image.cpp \
 440     src/map/mbtilesmap.cpp \
 441     src/map/osm.cpp \
 442     src/map/rectd.cpp \
 443     src/map/rmap.cpp \
 444     src/map/textitem.cpp \
 445     src/map/aqmmap.cpp \
 446     src/map/mapsforgemap.cpp \
 447     src/map/worldfilemap.cpp \
 448     src/map/hillshading.cpp \
 449     src/data/gpsdumpparser.cpp \
 450     src/data/twonavparser.cpp \
 451     src/data/address.cpp \
 452     src/data/itnparser.cpp \
 453     src/data/onmoveparsers.cpp \
 454     src/data/ov2parser.cpp \
 455     src/data/waypoint.cpp \
 456     src/data/data.cpp \
 457     src/data/poi.cpp \
 458     src/data/track.cpp \
 459     src/data/route.cpp \
 460     src/data/path.cpp \
 461     src/data/gpxparser.cpp \
 462     src/data/tcxparser.cpp \
 463     src/data/csvparser.cpp \
 464     src/data/kmlparser.cpp \
 465     src/data/fitparser.cpp \
 466     src/data/igcparser.cpp \
 467     src/data/nmeaparser.cpp \
 468     src/data/oziparsers.cpp \
 469     src/data/locparser.cpp \
 470     src/data/slfparser.cpp \
 471     src/data/exifparser.cpp \
 472     src/data/cupparser.cpp \
 473     src/data/gpiparser.cpp \
 474     src/data/smlparser.cpp \
 475     src/data/geojsonparser.cpp
 476
 477 DEFINES += APP_VERSION=\\\"$$VERSION\\\" \
 478     QT_NO_DEPRECATED_WARNINGS
 479
 480 RESOURCES += gpxsee.qrc
 481 TRANSLATIONS = lang/gpxsee_en.ts \
 482     lang/gpxsee_cs.ts \
 483     lang/gpxsee_sv.ts \
 484     lang/gpxsee_de.ts \
 485     lang/gpxsee_ru.ts \
 486     lang/gpxsee_fi.ts \
 487     lang/gpxsee_fr.ts \
 488     lang/gpxsee_pl.ts \
 489     lang/gpxsee_nb.ts \
 490     lang/gpxsee_da.ts \
 491     lang/gpxsee_tr.ts \
 492     lang/gpxsee_es.ts \
 493     lang/gpxsee_pt_BR.ts \
 494     lang/gpxsee_uk.ts \
 495     lang/gpxsee_hu.ts \
 496     lang/gpxsee_it.ts \
 497     lang/gpxsee_eo.ts \
 498     lang/gpxsee_zh.ts \
 499     lang/gpxsee_ca.ts \
 500     lang/gpxsee_ko.ts
 501
 502 macx {
 503     RESOURCES += theme-grayscale.qrc
 504
 505     ICON = icons/app/gpxsee.icns
 506     QMAKE_INFO_PLIST = pkg/mac/Info.plist
 507     locale.path = Contents/Resources/translations
 508     locale.files = $$files(lang/*.qm)
 509     crs.path = Contents/Resources
 510     crs.files = data/CRS
 511     maps.path = Contents/Resources
 512     maps.files = data/maps
 513     symbols.path = Contents/Resources/symbols
 514     symbols.files = $$files(icons/symbols/*.png)
 515     icons.path = Contents/Resources/icons
 516     icons.files = $$files(icons/formats/*.icns)
 517     lproj.path = Contents/Resources
 518     lproj.files = $$files(pkg/mac/lproj/*)
 519     QMAKE_BUNDLE_DATA += locale maps symbols icons crs lproj
 520 }
 521
 522 win32 {
 523     CONFIG += no_batch
 524     RESOURCES += theme-color.qrc
 525
 526     QMAKE_TARGET_DESCRIPTION = GPXSee
 527     QMAKE_TARGET_COPYRIGHT = Copyright (c) 2015-2024 Martin Tuma
 528     RC_ICONS = icons/app/gpxsee.ico \
 529         icons/formats/gpx.ico \
 530         icons/formats/tcx.ico \
 531         icons/formats/kml.ico \
 532         icons/formats/fit.ico \
 533         icons/formats/igc.ico \
 534         icons/formats/nmea.ico \
 535         icons/formats/plt.ico \
 536         icons/formats/rte.ico \
 537         icons/formats/wpt.ico \
 538         icons/formats/loc.ico \
 539         icons/formats/slf.ico \
 540         icons/formats/json.ico \
 541         icons/formats/cup.ico \
 542         icons/formats/gpi.ico \
 543         icons/formats/sml.ico \
 544         icons/formats/img.ico \
 545         icons/formats/jnx.ico \
 546         icons/formats/kap.ico \
 547         icons/formats/map.ico \
 548         icons/formats/mbts.ico \
 549         icons/formats/rmap.ico \
 550         icons/formats/tba.ico \
 551         icons/formats/aqm.ico \
 552         icons/formats/sqlt.ico \
 553         icons/formats/ov2.ico \
 554         icons/formats/itn.ico \
 555         icons/formats/wld.ico \
 556         icons/formats/omd.ico \
 557         icons/formats/ghp.ico \
 558         icons/formats/qct.ico \
 559         icons/formats/trk.ico \
 560         icons/formats/gemf.ico \
 561         icons/formats/000.ico \
 562         icons/formats/031.ico
 563     DEFINES += _USE_MATH_DEFINES \
 564         NOGDI
 565 }
 566
 567 unix:!macx:!android {
 568     RESOURCES += theme-grayscale.qrc
 569
 570     isEmpty(PREFIX):PREFIX = /usr/local
 571     maps.files = $$files(data/maps/*)
 572     maps.path = $$PREFIX/share/gpxsee/maps
 573     crs.files = $$files(data/CRS/*)
 574     crs.path = $$PREFIX/share/gpxsee/CRS
 575     symbols.files = $$files(icons/symbols/*.png)
 576     symbols.path = $$PREFIX/share/gpxsee/symbols
 577     locale.files = $$files(lang/*.qm)
 578     locale.path = $$PREFIX/share/gpxsee/translations
 579     icon.files = $$files(icons/app/hicolor/*)
 580     icon.path = $$PREFIX/share/icons/hicolor
 581     desktop.files = pkg/linux/gpxsee.desktop
 582     desktop.path = $$PREFIX/share/applications
 583     mime.files = pkg/linux/gpxsee.xml
 584     mime.path = $$PREFIX/share/mime/packages
 585     appdata.files = pkg/linux/gpxsee.appdata.xml
 586     appdata.path = $$PREFIX/share/metainfo
 587     target.path = $$PREFIX/bin
 588     INSTALLS += target maps crs symbols locale icon desktop mime appdata
 589 }
 590
 591 android {
 592     QT += core5compat
 593
 594     HEADERS += src/GUI/navigationwidget.h
 595     SOURCES += src/GUI/navigationwidget.cpp
 596
 597     RESOURCES += theme-color.qrc
 598
 599     defineReplace(versionCode) {
 600         segments = $$split(1, ".")
 601         for (segment, segments): \
 602             vCode = "$$first(vCode)$$format_number($$segment, width=3 zeropad)"
 603         contains(ANDROID_TARGET_ARCH, armeabi-v7a): \
 604             suffix = 0
 605         contains(ANDROID_TARGET_ARCH, arm64-v8a): \
 606             suffix = 1
 607         contains(ANDROID_TARGET_ARCH, x86): \
 608             suffix = 2
 609         contains(ANDROID_TARGET_ARCH, x86_64): \
 610             suffix = 3
 611
 612         return($$first(vCode)$$first(suffix))
 613     }
 614
 615     !include($$OPENSSL_PATH/openssl.pri) {
 616         message("OpenSSL not found, building without HTTPS support!")
 617     }
 618
 619     ANDROID_TARGET_SDK_VERSION = 33
 620     ANDROID_VERSION_NAME = $$VERSION
 621     ANDROID_VERSION_CODE = $$versionCode($$ANDROID_VERSION_NAME)
 622     ANDROID_PACKAGE_SOURCE_DIR = $$PWD/pkg/android
 623     DISTFILES += \
 624         pkg/android/AndroidManifest.xml \
 625         pkg/android/build.gradle \
 626         pkg/android/res/values/libs.xml
 627
 628     maps.files = $$files(data/maps/*)
 629     maps.path = /assets/maps
 630     crs.files = $$files(data/CRS/*)
 631     crs.path = /assets/CRS
 632     symbols.files = $$files(icons/symbols/*.png)
 633     symbols.path = /assets/symbols
 634     translations.files = $$files(lang/*.qm)
 635     translations.path = /assets/translations
 636     INSTALLS += maps crs symbols translations
 637 }