dyskinesia.pro

   1 ###############################################################################
   2 ## WARNING!
   3 ## remove `CONFIG += use_leveldb` to use JSON history format!
   4 ###############################################################################
   5
   6 TEMPLATE = app
   7 TARGET = dyskinesia
   8
   9 QT -= xml
  10 QT += gui network
  11
  12 CONFIG += packdata
  13 #CONFIG += json_history
  14
  15 #CONFIG += use_hamsterdb
  16 #CONFIG += use_leveldb
  17 CONFIG += use_bhf
  18
  19 !win32 {
  20   CONFIG += otr
  21   LIBS += -lX11
  22 }
  23
  24
  25 CONFIG += usessl
  26
  27 CONFIG += qt warn_on
  28 CONFIG += debug_and_release
  29 #CONFIG += debug
  30 #CONFIG += release
  31
  32 #QMAKE_CFLAGS_RELEASE ~= s/\-O./-Os
  33 #QMAKE_CXXFLAGS_RELEASE ~= s/\-O./-Os
  34
  35 ##QMAKE_CFLAGS_RELEASE ~= s/\-O./-O2
  36 ##QMAKE_CXXFLAGS_RELEASE ~= s/\-O./-O2
  37
  38 QMAKE_CFLAGS_RELEASE += -march=native
  39 QMAKE_CXXFLAGS_RELEASE += -march=native
  40 QMAKE_CFLAGS_RELEASE += -mtune=native
  41 QMAKE_CXXFLAGS_RELEASE += -mtune=native
  42
  43 QMAKE_LFLAGS_RELEASE += -s
  44
  45
  46 DESTDIR = .
  47 OBJECTS_DIR = _build/obj
  48 UI_DIR = _build/uic
  49 MOC_DIR = _build/moc
  50 RCC_DIR = _build/rcc
  51
  52
  53 !CONFIG(use_hamsterdb) {
  54   !CONFIG(use_leveldb) {
  55     !CONFIG(use_bhf) {
  56       CONFIG += json_history
  57     }
  58   }
  59 }
  60
  61 CONFIG(otr) {
  62   #LIBS += -lotr
  63   DEFINES += USE_OTR
  64   CONFIG += link_pkgconfig
  65   PKGCONFIG += libotr
  66 }
  67
  68 CONFIG(use_hamsterdb) {
  69   DEFINES += USE_HAMSTER_DB
  70   LIBS += $$PWD/hamsterdb/lib/libhamsterdb.a
  71   INCLUDEPATH += $$PWD/hamsterdb
  72 }
  73
  74 CONFIG(use_leveldb) {
  75   DEFINES += USE_LEVEL_DB LEVELDB_PLATFORM_POSIX OS_LINUX
  76   LIBS += $$PWD/leveldb/lib/libleveldb.a
  77   INCLUDEPATH += $$PWD/leveldb
  78 }
  79
  80
  81 CONFIG(usessl) {
  82   DEFINES += USE_SSL
  83 }
  84
  85
  86 CONFIG(staticpicplugs) {
  87   QTPLUGIN += qgif4 qjpeg4 qmng4 qico4 qsvg4 qtiff4
  88   DEFINES += USE_STATIC_PICPLUGS
  89   DEFINES += QT_STATICPLUGIN
  90   LIBS += -Lc:/Qtsdk/qt/plugins/imageformats
  91 }
  92
  93
  94 include(src/psycproto/psycproto.pri)
  95
  96 #include(src/test/parser/test.pri)
  97 #include(src/test/socket/test.pri)
  98
  99 include(src/main.pri)
 100
 101 CONFIG(packdata) {
 102   RESOURCES += $$PWD/data.qrc
 103 }
 104
 105 RESOURCES += $$PWD/icons.qrc
 106
 107 win32 {
 108   RC_FILE = winrc.rc
 109 }