configure.ac

   1 AC_PREREQ(2.60)
   2 AC_INIT(libmpdclient, 2.5, musicpd-dev-team@lists.sourceforge.net)
   3 AC_CONFIG_SRCDIR([src/connection.c])
   4 AC_CONFIG_AUX_DIR(build)
   5 AM_INIT_AUTOMAKE([foreign 1.10 dist-bzip2 subdir-objects])
   6 AM_CONFIG_HEADER([config.h])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_SUBST(MAJOR_VERSION,2)
  10 AC_SUBST(MINOR_VERSION,5)
  11 AC_SUBST(PATCH_VERSION,0)
  12
  13 LIBMPDCLIENT_LIBTOOL_VERSION=2:5:0
  14 AC_SUBST(LIBMPDCLIENT_LIBTOOL_VERSION)
  15
  16 # Remove the check for c++ and fortran compiler
  17 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  18 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  19
  20 dnl Check for programs
  21 AC_PROG_CC_C99
  22 AC_PROG_INSTALL
  23
  24 AC_PROG_LD
  25 AM_CONDITIONAL(HAVE_GNU_LD, test x$with_gnu_ld = xyes)
  26
  27 AC_LIBTOOL_WIN32_DLL
  28 AC_PROG_LIBTOOL
  29
  30 AC_PATH_PROG(DOXYGEN, doxygen)
  31 AM_CONDITIONAL(DOXYGEN, test x$DOXYGEN != x)
  32 AC_SUBST(DOXYGEN)
  33
  34
  35 dnl
  36 dnl initialize variables
  37 dnl
  38
  39 set -- $CFLAGS
  40
  41
  42 dnl
  43 dnl OS specific defaults
  44 dnl
  45
  46 AC_CANONICAL_HOST
  47
  48 case "$host_os" in
  49 mingw32* | windows*)
  50         LIBS="$LIBS -lws2_32"
  51         ;;
  52 esac
  53
  54
  55 dnl
  56 dnl Check for libraries
  57 dnl
  58
  59 AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket",)
  60 AC_CHECK_LIB(nsl, gethostbyname, LIBS="$LIBS -lnsl",)
  61
  62
  63 dnl
  64 dnl build options
  65 dnl
  66
  67 AC_ARG_ENABLE(tcp,
  68         AS_HELP_STRING([--disable-tcp],
  69                 [Disable TCP support (default: enabled)]),,
  70         [enable_tcp=yes])
  71 if test "x$enable_tcp" = xyes; then
  72         AC_DEFINE([ENABLE_TCP], 1, [Define to enable TCP support])
  73 fi
  74
  75 AC_ARG_ENABLE(werror,
  76         AS_HELP_STRING([--enable-werror],
  77                 [Treat warnings as errors (default: disabled)]),
  78         ENABLE_WERROR=$enableval,
  79         ENABLE_WERROR=no)
  80
  81 if test "x$ENABLE_WERROR" = xyes; then
  82         AM_CFLAGS="$AM_CFLAGS -Werror -pedantic-errors"
  83 fi
  84
  85 AC_ARG_ENABLE(debug,
  86         AS_HELP_STRING([--enable-debug],
  87                 [Enable debugging (default: disabled)]),
  88         ENABLE_DEBUG=$enableval,
  89         ENABLE_DEBUG=no)
  90
  91 if test "x$ENABLE_DEBUG" = xno; then
  92         AM_CFLAGS="$AM_CFLAGS -DNDEBUG"
  93 fi
  94
  95
  96 dnl
  97 dnl CFLAGS
  98 dnl
  99
 100 AC_SUBST(AM_CFLAGS)
 101 AC_SUBST(AM_CPPFLAGS)
 102
 103 WANTED_CFLAGS="-Wall -W -Wextra -Wno-deprecated-declarations -Wmissing-prototypes -Wshadow -Wpointer-arith -Wstrict-prototypes -Wcast-qual -Wwrite-strings"
 104 for flag in $WANTED_CFLAGS ; do
 105         AX_CHECK_COMPILER_FLAGS([$flag], [CFLAGS="$CFLAGS $flag"],)
 106 done
 107
 108 dnl
 109 dnl Compile-time options
 110 dnl
 111
 112 AC_ARG_WITH([default-socket],
 113         AC_HELP_STRING([--with-default-socket=PATH],
 114                 [default path of the socket file @<:@/var/run/mpd/socket@:>@]),,
 115         [with_default_socket=auto])
 116
 117 if test x$with_default_socket = xauto; then
 118         case "$host_os" in
 119         mingw32* | windows*)
 120                 # no UNIX domain sockets on WIN32
 121                 with_default_socket=no
 122                 ;;
 123         *)
 124                 with_default_socket=/var/run/mpd/socket
 125                 ;;
 126         esac
 127 fi
 128
 129 if test x$with_default_socket != xno; then
 130         AC_DEFINE_UNQUOTED([DEFAULT_SOCKET], ["$with_default_socket"],
 131                 [Default UNIX socket path])
 132 fi
 133
 134 AC_ARG_WITH([default-host],
 135         AC_HELP_STRING([--with-default-host=ARG],
 136                 [default MPD host @<:@localhost@:>@]),,
 137         [with_default_host=localhost])
 138 AC_DEFINE_UNQUOTED([DEFAULT_HOST], ["$with_default_host"], [Default MPD host])
 139
 140 AC_ARG_WITH([default-port],
 141         AC_HELP_STRING([--with-default-port=ARG],
 142                 [default MPD port @<:@6600@:>@]),,
 143         [with_default_port=6600])
 144 AC_DEFINE_UNQUOTED([DEFAULT_PORT], [$with_default_port], [Default MPD port])
 145
 146
 147 dnl
 148 dnl Done
 149 dnl
 150
 151 AC_OUTPUT([Makefile include/mpd/version.h libmpdclient.pc doc/doxygen.conf])