configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(WvStreams, 4.5.1, wvstreams-devel@googlegroups.com, wvstreams)
   3 SO_VERSION=4.5
   4
   5 # append to a variable without introducing superfluous white space
   6 AC_DEFUN([WV_APPEND],[
   7     if test -z "$$1"; then
   8         $1="$2"
   9     else
  10         $1="$$1 $2"
  11     fi
  12 ])
  13
  14 QT_SEARCH_PATH="
  15 $prefix
  16 /usr
  17 $libdir/qt-3.1
  18 $libdir/qt3
  19 $libdir/qt
  20 $datadir/qt3
  21 $datadir/qt
  22 /usr
  23 /usr/lib/qt3
  24 /usr/lib/qt-3.1
  25 /usr/share/qt3
  26 /usr/lib/qt
  27 /usr/share/qt
  28 "
  29
  30 AC_CONFIG_SRCDIR(streams/wvstream.cc)
  31
  32 AC_ARG_ENABLE(debug,
  33               AC_HELP_STRING([--disable-debug],
  34                              [strip debug information]))
  35
  36 AC_ARG_ENABLE(fatal-warnings,
  37               AC_HELP_STRING([--enable-fatal-warnings],
  38                              [turn warnings into errors]))
  39
  40 AC_ARG_ENABLE(optimization,
  41               AC_HELP_STRING([--disable-optimization],
  42                              [optimization options]))
  43
  44 AC_ARG_ENABLE(resolver-fork,
  45               AC_HELP_STRING([--disable-resolver-fork],
  46                              [WvResolver background name resolution (debugging)]))
  47
  48 AC_ARG_ENABLE(delete-detector,
  49               AC_HELP_STRING([--enable-delete-detector],
  50                              [Delete detector (reference counting)]))
  51
  52 AC_ARG_ENABLE(warnings,
  53               AC_HELP_STRING([--disable-warnings],
  54                              [extra warnings]))
  55
  56 AC_ARG_ENABLE(testgui,
  57               AC_HELP_STRING([--disable-testgui],
  58                              [GUI for unit tests]))
  59
  60 AC_ARG_WITH(dbus, AC_HELP_STRING([--with-dbus], [DBUS]))
  61 AC_ARG_WITH(openssl, AC_HELP_STRING([--with-openssl], [OpenSSL >= 0.9.7 (required)]))
  62 AC_ARG_WITH(pam, AC_HELP_STRING([--with-pam], [PAM]))
  63 AC_ARG_WITH(tcl, AC_HELP_STRING([--with-tcl], [Tcl]))
  64 AC_ARG_WITH(qt, AC_HELP_STRING([--with-qt], [Qt]))
  65 AC_ARG_WITH(zlib, AC_HELP_STRING([--with-zlib], [zlib (required)]))
  66 AC_ARG_WITH(valgrind, AC_HELP_STRING([--with-valgrind], [Valgrind]))
  67
  68 AC_ARG_VAR(MOC, [Qt meta object compiler])
  69 AC_ARG_VAR(WEAVER_BUILD_INFO, [Extra version info])
  70
  71 # avoid autoconf's default values, but keep those the user might have given
  72 CFLAGS="$CFLAGS"
  73 CXXFLAGS="$CXXFLAGS"
  74
  75 AC_PROG_CC
  76 AC_PROG_CXX
  77 AC_PROG_CPP
  78 AC_PROG_CXXCPP
  79 AC_PROG_INSTALL
  80 AC_PROG_LN_S
  81 AC_PROG_MAKE_SET
  82 AC_PROG_RANLIB
  83
  84 # Detect target build environment
  85 AC_CANONICAL_TARGET
  86 case "$target" in
  87     *-linux*)
  88         ARCH_SUBDIRS="linuxstreams"
  89         OS="LINUX"
  90         ;;
  91     *-sunos*|*-solaris*)
  92         ARCH_SUBDIRS=""
  93         ac_libs="-lstdc++ -lgcc_s -ldl -lm -lc"
  94         OS="SOLARIS"
  95         ;;
  96     *-win*)
  97         ARCH_SUBDIRS="win32"
  98         OS="WIN32"
  99         ;;
 100     *-apple*)
 101         ARCH_SUBDIRS=""
 102         OS="MACOS"
 103         ;;
 104     *)
 105         ARCH_SUBDIRS=""
 106         OS="OTHER"
 107         ;;
 108 esac
 109
 110 AC_SUBST(target)
 111 AC_SUBST(ARCH_SUBDIRS)
 112 AC_SUBST(OS)
 113
 114 # Detect endianness
 115 AC_C_BIGENDIAN
 116
 117 # Look for __attribute__ ((deprecated))
 118 CPPFLAGS_save="$CPPFLAGS"
 119 WV_APPEND(CPPFLAGS, -Werror)
 120 AC_MSG_CHECKING(for __attribute__ ((deprecated)))
 121 AC_COMPILE_IFELSE(
 122 [#include "confdefs.h"
 123 void f() __attribute__ ((deprecated));
 124 void f()
 125 {
 126 }
 127
 128 int main()
 129 {
 130     return 0;
 131 }
 132 ],
 133                   [AC_MSG_RESULT([yes])
 134                    AC_DEFINE([ATTR_DEPRECATED],
 135                              [__attribute__ ((deprecated))],
 136                              [Compiler warning on deprecated functions])],
 137                   [AC_MSG_RESULT([no])
 138                    AC_DEFINE([ATTR_DEPRECATED], [],
 139                              [Compiler warning on deprecated functions])])
 140 CPPFLAGS="$CPPFLAGS_save"
 141
 142 # argp
 143 USE_WVSTREAMS_ARGP=0
 144 AC_CHECK_HEADERS(argp.h)
 145 AC_CHECK_FUNC(argp_parse)
 146 if test "$ac_cv_func_argp_parse" != yes \
 147     -o "$ac_cv_header_argp_h" != yes ; then
 148     (cd argp && ./configure "$@")
 149     USE_WVSTREAMS_ARGP=1
 150 fi
 151
 152 # Function checks
 153 AC_HEADER_DIRENT
 154
 155 AC_FUNC_ALLOCA
 156
 157 AC_CHECK_HEADERS(execinfo.h)
 158
 159 # Check for error_t
 160 AC_CHECK_HEADERS([argz.h errno.h])
 161 AC_CHECK_TYPE(error_t,, [AC_DEFINE([error_t], [int],
 162                                   [Define to a type to use for `error_t' if it is not otherwise available.])
 163 AC_DEFINE([__error_t_defined], [1], [Define so that glibc/gnulib argp.h
 164     does not typedef error_t.])],dnl `
 165 [#if HAVE_ARGZ_H
 166 # include <argz.h>
 167 #else
 168 # if HAVE_ERRNO_H
 169 #  include <errno.h>
 170 # endif
 171 #endif])
 172
 173 # Check for size of ethernet addresses
 174 AC_CHECK_HEADERS([sys/socket.h])
 175 AC_CHECK_HEADERS([net/if.h], [], [],
 176 [#include <stdio.h>
 177 #if STDC_HEADERS
 178 # include <stdlib.h>
 179 # include <stddef.h>
 180 #else
 181 # if HAVE_STDLIB_H
 182 #  include <stdlib.h>
 183 # endif
 184 #endif
 185 #if HAVE_SYS_SOCKET_H
 186 # include <sys/socket.h>
 187 #endif
 188 ])
 189 AC_CHECK_HEADERS([net/ethernet.h], [], [],
 190 [#include <stdio.h>
 191 #if STDC_HEADERS
 192 # include <stdlib.h>
 193 # include <stddef.h>
 194 #else
 195 # if HAVE_STDLIB_H
 196 #  include <stdlib.h>
 197 # endif
 198 #endif
 199 #if HAVE_SYS_SOCKET_H
 200 # include <sys/socket.h>
 201 #endif
 202 ])
 203 AC_CHECK_HEADERS([netinet/if_ether.h], [], [],
 204 [#include <stdio.h>
 205 #if STDC_HEADERS
 206 # include <stdlib.h>
 207 # include <stddef.h>
 208 #else
 209 # if HAVE_STDLIB_H
 210 #  include <stdlib.h>
 211 # endif
 212 #endif
 213 #if HAVE_SYS_SOCKET_H
 214 # include <sys/socket.h>
 215 #endif
 216 #if HAVE_NET_IF_H
 217 # include <net/if.h>
 218 #endif
 219 ])
 220 AC_CHECK_DECL(ETHER_ADDR_LEN,,
 221               AC_CHECK_TYPE(ether_addr_t,
 222                             AC_DEFINE([ETHER_ADDR_LEN], [sizeof(ether_addr_t)],
 223                                       [Size of ethernet address]),
 224                             AC_DEFINE([ETHER_ADDR_LEN], [6]),
 225 [#include <stdio.h>
 226 #if HAVE_SYS_TYPES_H
 227 # include <sys/types.h>
 228 #endif
 229 #if STDC_HEADERS
 230 # include <stdlib.h>
 231 # include <stddef.h>
 232 #else
 233 # if HAVE_STDLIB_H
 234 #  include <stdlib.h>
 235 # endif
 236 #endif
 237 #if HAVE_SYS_SOCKET_H
 238 # include <sys/socket.h>
 239 #endif
 240 #if HAVE_NET_ETHERNET_H
 241 # include <net/ethernet.h>
 242 #endif
 243 #if HAVE_NET_IF_H
 244 # include <net/if.h>
 245 #endif
 246 #if HAVE_NETINET_IF_ETHER_H
 247 # include <netinet/if_ether.h>
 248 #endif
 249 ]),
 250 [#include <stdio.h>
 251 #if HAVE_SYS_TYPES_H
 252 # include <sys/types.h>
 253 #endif
 254 #if STDC_HEADERS
 255 # include <stdlib.h>
 256 # include <stddef.h>
 257 #else
 258 # if HAVE_STDLIB_H
 259 #  include <stdlib.h>
 260 # endif
 261 #endif
 262 #if HAVE_SYS_SOCKET_H
 263 # include <sys/socket.h>
 264 #endif
 265 #if HAVE_NET_ETHERNET_H
 266 # include <net/ethernet.h>
 267 #endif
 268 #if HAVE_NET_IF_H
 269 # include <net/if.h>
 270 #endif
 271 #if HAVE_NETINET_IF_ETHER_H
 272 # include <netinet/if_ether.h>
 273 #endif
 274 ])
 275
 276 # Check for basic Internet support
 277 AC_CHECK_HEADERS([netdb.h])
 278 AC_CHECK_HEADERS([netinet/in.h])
 279 AC_CHECK_HEADERS([netinet/in_systm.h])
 280 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 281 [#include <stdio.h>
 282 #if HAVE_SYS_TYPES_H
 283 # include <sys/types.h>
 284 #endif
 285 #if STDC_HEADERS
 286 # include <stdlib.h>
 287 # include <stddef.h>
 288 #else
 289 # if HAVE_STDLIB_H
 290 #  include <stdlib.h>
 291 # endif
 292 #endif
 293 #if HAVE_NETINET_IN_H
 294 # include <netinet/in.h>
 295 #endif
 296 #if HAVE_NETINET_IN_SYSTM_H
 297 # include <netinet/in_systm.h>
 298 #endif
 299 ])
 300 AC_CHECK_HEADERS([netinet/tcp.h])
 301
 302 # Check for advanced Linux-style modem support
 303 AC_CHECK_HEADERS([linux/serial.h])
 304 AC_CHECK_FUNCS([cfmakeraw])
 305
 306 # Detect hard-linking based on LN_S's behaviour
 307 AC_MSG_CHECKING([whether ln works...])
 308 case "$LN_S" in
 309     ln*)
 310         LN='ln'
 311         AC_MSG_RESULT([yes])
 312         ;;
 313     *)
 314         LN="$LN_S"
 315         AC_MSG_RESULT([no, using $LN])
 316         ;;
 317 esac
 318 AC_SUBST(LN)
 319
 320 # Setting the default language to C++ means that CXX and CXXCPP will be
 321 # used for compile tests.
 322 AC_LANG(C++)
 323
 324 # __libc_stack_end isn't available to shared libraries with some libc versions
 325 AC_MSG_CHECKING([whether __libc_stack_end is public])
 326 AH_TEMPLATE([HAVE_LIBC_STACK_END], [Whether libc supports __libc_stack_end])
 327 LDFLAGS_save="$LDFLAGS"
 328 WV_APPEND(LDFLAGS, [-Wl,-z,defs -shared])
 329 HAVE_LIBC_STACK_END=no
 330 AC_TRY_LINK([extern const void *__libc_stack_end; ],
 331             [volatile const void *x = __libc_stack_end; ],
 332             [HAVE_LIBC_STACK_END=yes; ])
 333 if test "$HAVE_LIBC_STACK_END" = "yes"; then
 334         AC_DEFINE([HAVE_LIBC_STACK_END])
 335 fi
 336 AC_MSG_RESULT([$HAVE_LIBC_STACK_END])
 337 LDFLAGS="$LDFLAGS_save"
 338
 339 # Detect pkg-config
 340 AC_PATH_PROG([PKGCONFIG], [pkg-config], [no])
 341 if test "$PKGCONFIG" = "no"; then
 342     AC_MSG_WARN([pkg-config is not installed])
 343 fi
 344
 345 if test "$enable_debug" != "no"; then
 346     AC_DEFINE_UNQUOTED(VER_STRING_EXTRA, [" (`whoami`@`hostname`$VER_STRING_EXTRA)"], [Extra version string.])
 347 fi
 348
 349 # resolver-fork
 350 if test "$enable_resolver_fork" = "no"; then
 351     AC_DEFINE(WVRESOLVER_SKIP_FORK,,
 352               [Define to disable WvResolver forking for debugging with gdb.])
 353 fi
 354
 355 # xplc delete detector
 356 if test "$enable_delete_detector" = "yes"; then
 357     AC_DEFINE(ENABLE_DELETE_DETECTOR,,
 358               [Define to enable the XPLC delete detector.])
 359 fi
 360
 361 # dbus
 362 if test "$with_dbus" != "no"; then
 363     WV_APPEND(CPPFLAGS, -DDBUS_API_SUBJECT_TO_CHANGE -Iinclude/dbus-upstream)
 364     if test "$with_dbus" = "" -o "$with_dbus" = "yes"; then
 365         DBUS_LIBDIR="$(pkg-config --variable=libdir dbus-1)"
 366         if test -z "$DBUS_LIBDIR"; then
 367             DBUS_LIBDIR=/usr/lib  # Default path for static linking
 368         fi
 369         WV_APPEND(CPPFLAGS, [`pkg-config --cflags dbus-1`])
 370         WV_APPEND(LDFLAGS, [`pkg-config --libs-only-L dbus-1`])
 371     else
 372         DBUS_LIBDIR=$with_dbus/dbus/.libs
 373         WV_APPEND(CPPFLAGS, -I$with_dbus)
 374         WV_APPEND(LDFLAGS, -L$DBUS_LIBDIR)
 375     fi
 376
 377     AC_CHECK_HEADERS(dbus/dbus.h,, [with_dbus=no])
 378     LIBS_save="$LIBS"
 379     LIBS="$LIBS $DBUS_LIBDIR/libdbus-1.a"
 380     with_dbus=no
 381     AC_TRY_LINK([extern "C" void dbus_message_new(); ],
 382                 [dbus_message_new(); ],
 383                 [with_dbus=])
 384     LIBS="$LIBS_save"
 385
 386     if test "$with_dbus" != "no"; then
 387         AC_DEFINE(WITH_DBUS,,
 388                   [Define to enable DBUS support.])
 389         LIBS_DBUS=$DBUS_LIBDIR/libdbus-1.a
 390     fi
 391 fi
 392
 393 # BSD sockets, if you're on Solaris
 394 AC_CHECK_LIB(socket, bind)
 395
 396 # openssl
 397 if test "$with_openssl" != "no"; then
 398     if test "$with_openssl" != ""; then
 399         WV_APPEND(CPPFLAGS, [-I$with_openssl/include])
 400         WV_APPEND(LDFLAGS, [-L$with_openssl])
 401     fi
 402     AC_CHECK_HEADERS(openssl/ssl.h,, [with_openssl=no],
 403                      [#define OPENSSL_NO_KRB5])
 404     LIBS_save="$LIBS"
 405     AC_CHECK_LIB(crypto, X509_free)
 406     AC_CHECK_LIB(ssl, SSL_has_matching_session_id,, [with_openssl=no])
 407     AC_CHECK_LIB(ssl, POLICY_MAPPING_new,, [with_openssl_policy_mapping=no])
 408     if test "$with_openssl_policy_mapping" != "no"; then
 409         AC_DEFINE([HAVE_OPENSSL_POLICY_MAPPING], [1],
 410             [Whether libssl has the POLICY_MAPPING features (0.9.8 and up)])
 411     fi
 412     LIBS="$LIBS_save"
 413     if test "$with_openssl" != "no"; then
 414         LIBS_SSL="-lcrypto -lssl"
 415     fi
 416 fi
 417
 418 # readline
 419 if test "$with_readline" != "no"; then
 420     AC_CHECK_HEADERS(readline/readline.h,, [with_readline=no])
 421     AC_CHECK_LIB(readline, readline,, [with_readline=no])
 422 fi
 423
 424 # pam
 425 if test "$with_pam" != "no"; then
 426     AC_CHECK_HEADERS(security/pam_appl.h,, [with_pam=no])
 427     LIBS_save="$LIBS"
 428     AC_CHECK_LIB(pam, pam_start,, [with_pam=no])
 429     AC_MSG_CHECKING(for sane PAM implementation)
 430     AC_COMPILE_IFELSE(
 431 [#include "confdefs.h"
 432 #if HAVE_SECURITY_PAM_APPL_H
 433 # include <security/pam_appl.h>
 434 #endif
 435
 436 /* noconv: null PAM conversation function */
 437 int noconv(int num_msg, const struct pam_message **msgm,
 438         struct pam_response **response, void *userdata)
 439 {
 440     // if you need to ask things, it won't work
 441     return PAM_CONV_ERR;
 442 }
 443
 444 int main()
 445 {
 446     struct pam_conv c;
 447     c.conv = noconv;
 448     return 0;
 449 }
 450 ],
 451                       [AC_MSG_RESULT([yes])
 452                        AC_DEFINE([HAVE_BROKEN_PAM], [0])],
 453                       [AC_MSG_RESULT([no])
 454                        AC_DEFINE([HAVE_BROKEN_PAM], [1],
 455                                  [Solaris has a broken PAM implementation])])
 456     LIBS="$LIBS_save"
 457     if test "$with_pam" != "no" -a "$HAVE_BROKEN_PAM" != "1"; then
 458         LIBS_PAM=-lpam
 459     fi
 460 fi
 461
 462 # tcl
 463 if test "$with_tcl" != "no"; then
 464     CPPFLAGS_save="$CPPFLAGS"
 465     WV_APPEND(CPPFLAGS, -I/usr/include/tcl8.3)
 466     AC_CHECK_HEADERS(tcl.h,, [with_tcl=no])
 467     LIBS_save="$LIBS"
 468     AC_CHECK_LIB(tcl8.3, TclInterpInit,, [with_tcl=no])
 469     LIBS="$LIBS_save"
 470     if test "$with_tcl" != "no"; then
 471         CPPFLAGS="$CPPFLAGS_save"
 472         LIBS_TCL=-ltcl8.3
 473     fi
 474 fi
 475
 476 # qt
 477 if test "$with_qt" != "no"; then
 478     test "$with_qt" = yes && with_qt=
 479     AC_CACHE_CHECK([for Qt], [wv_cv_with_qt], [
 480         wv_cv_with_qt=no
 481         CPPFLAGS_save="$CPPFLAGS"
 482         LDFLAGS_save="$LDFLAGS"
 483         LIBS_save="$LIBS"
 484         for wv_qtdir in $with_qt $QTDIR $QT_SEARCH_PATH $(pkg-config --variable=prefix qt-mt); do
 485             eval wv_qtdir="$wv_qtdir"
 486             CPPFLAGS="$CPPFLAGS_save -I$wv_qtdir/include -I$wv_qtdir/include/qt3"
 487             LDFLAGS="$LDFLAGS_save -L$wv_qtdir/lib"
 488             LIBS="$LIBS_save -lqt-mt"
 489             AC_TRY_LINK([#include <qstring.h>],
 490                         [QString x("hello"); return 0; ],
 491                         [wv_cv_with_qt=$wv_qtdir; break])
 492         done
 493         CPPFLAGS="$CPPFLAGS_save"
 494         LDFLAGS="$LDFLAGS_save"
 495         LIBS="$LIBS_save"
 496     ])
 497     with_qt=$wv_cv_with_qt
 498     if test "$with_qt" != no; then
 499         WV_APPEND(CPPFLAGS, -I$with_qt/include -I$with_qt/include/qt3)
 500         if test "$wv_qtdir" != "/usr" ; then
 501                 # never explicitly include /usr/lib
 502                 WV_APPEND(LDFLAGS, -L$with_qt/lib)
 503         fi
 504         WV_APPEND(LIBS_QT, -lqt-mt)
 505     fi
 506     AC_PATH_PROG(MOC, moc, [moc not found], $with_qt/bin)
 507 fi
 508
 509 # valgrind
 510 if test "$with_valgrind" != "no"; then
 511     AC_CHECK_PROG(VALGRIND, valgrind, valgrind)
 512     AC_CHECK_HEADERS(valgrind/memcheck.h)
 513 fi
 514
 515 # zlib
 516 if test "$with_zlib" != "no"; then
 517     AC_CHECK_HEADERS(zlib.h,, [with_zlib=no])
 518     AC_CHECK_LIB(z, compress,, [with_zlib=no])
 519 fi
 520
 521 # Find out whether TR1 or Boost are available.
 522 AC_CHECK_HEADERS(tr1/functional)
 523 AC_CHECK_HEADERS(boost/function.hpp)
 524
 525 # When compiling with exceptions disabled and Boost, applications need
 526 # to provide an "exception handler", declared here.
 527 AC_CHECK_HEADERS(boost/throw_exception.hpp)
 528
 529 # check for missing packages
 530 missing_required=
 531 missing_devel=
 532 if test "$with_dbus" = "no"; then
 533     AC_MSG_WARN([DBUS is missing.])
 534     missing_devel=yes
 535 fi
 536 if test "$with_pam" = "no"; then
 537     AC_MSG_WARN([PAM is missing.])
 538     missing_devel=yes
 539 fi
 540 if test "$with_qt" = "no"; then
 541     AC_MSG_WARN([Qt is missing.])
 542     missing_devel=yes
 543 fi
 544 if test "$VALGRIND" = ""; then
 545     AC_MSG_WARN([Valgrind is missing.])
 546 fi
 547 if test "$with_openssl" = "no"; then
 548     AC_MSG_WARN([OpenSSL is missing.])
 549     missing_required="$missing_required OpenSSL>=0.9.7"
 550 fi
 551 if test "$with_readline" = "no"; then
 552     AC_MSG_WARN([readline is missing.])
 553 fi
 554 if test "$with_zlib" = "no"; then
 555     AC_MSG_WARN([zlib is missing.])
 556     missing_required="$missing_required zlib"
 557 fi
 558 if test "$ac_cv_header_tr1_functional" != "yes" \
 559      -a "$ac_cv_header_boost_function_hpp" != "yes"; then
 560     AC_MSG_WARN([both tr1/functional and boost/function.hpp are missing.])
 561     missing_required="$missing_required boost/function.hpp"
 562 fi
 563
 564 if test -n "$missing_required"; then
 565     AC_MSG_ERROR([Required dependencies missing:$missing_required])
 566 fi
 567
 568 if test "$VALGRIND" != ""; then
 569     VALGRIND="valgrind --tool=memcheck --leak-check=yes --num-callers=10 --suppressions=\$(WVSTREAMS_SRC)/wvstreams.supp"
 570     if valgrind --help | grep log-file >/dev/null; then
 571         VALGRIND="$VALGRIND --log-file=valgrind.log"
 572     else
 573         VALGRIND="$VALGRIND --logfile=valgrind.log"
 574     fi
 575 fi
 576
 577
 578 # Compiler is always posix if invoking this configure script
 579 COMPILER_STANDARD=posix
 580
 581 AC_SUBST(SO_VERSION)
 582
 583 AC_SUBST(USE_WVSTREAMS_ARGP)
 584
 585 AC_SUBST(enable_debug)
 586 AC_SUBST(enable_optimization)
 587 AC_SUBST(enable_resolver_fork)
 588 AC_SUBST(enable_delete_detector)
 589 AC_SUBST(enable_warnings)
 590 AC_SUBST(enable_testgui)
 591
 592 AC_SUBST(with_dbus)
 593 AC_SUBST(with_openssl)
 594 AC_SUBST(with_openssl_policy_mapping)
 595 AC_SUBST(with_pam)
 596 AC_SUBST(with_readline)
 597 AC_SUBST(with_qt)
 598 AC_SUBST(with_tcl)
 599 AC_SUBST(with_zlib)
 600
 601 AC_SUBST(LIBS_DBUS)
 602 AC_SUBST(LIBS_QT)
 603 AC_SUBST(LIBS_PAM)
 604 AC_SUBST(LIBS_TCL)
 605
 606 AC_SUBST(ac_libs)
 607 AC_SUBST(COMPILER_STANDARD)
 608
 609 AC_DEFINE_UNQUOTED([VERBOSE_PACKAGE_VERSION],["$PACKAGE_VERSION$WEAVER_BUILD_INFO"],[Verbose package version])
 610
 611 AC_CONFIG_FILES(config.mk)
 612 AC_CONFIG_FILES([pkgconfig/libuniconf.pc
 613                  pkgconfig/libuniconf-uninstalled.pc
 614                  pkgconfig/libwvbase.pc
 615                  pkgconfig/libwvbase-uninstalled.pc
 616                  pkgconfig/libwvdbus.pc
 617                  pkgconfig/libwvdbus-uninstalled.pc
 618                  pkgconfig/libwvqt.pc
 619                  pkgconfig/libwvqt-uninstalled.pc
 620                  pkgconfig/libwvstreams.pc
 621                  pkgconfig/libwvstreams-uninstalled.pc
 622                  pkgconfig/libwvutils.pc
 623                  pkgconfig/libwvutils-uninstalled.pc
 624                  pkgconfig/libwvtest.pc
 625                  pkgconfig/libwvtest-uninstalled.pc])
 626
 627 AC_CONFIG_HEADERS(include/wvautoconf.h)
 628
 629 AC_OUTPUT
 630
 631 # Now convert PACKAGE_* macros into WVPACKAGE_* in include/wvautoconf.h
 632 sed 's,\(\#define.*\)PACKAGE,\1WVPACKAGE,' include/wvautoconf.h > include/wvautoconf.h.new
 633 if test "x$?" = "x0"; then
 634     if ! diff include/wvautoconf.h include/wvautoconf.h.new >/dev/null; then
 635         mv include/wvautoconf.h.new include/wvautoconf.h
 636     else
 637         rm include/wvautoconf.h.new
 638     fi
 639 fi